菜单 QML 类型

菜单弹出窗口，可以用作上下文菜单或弹出菜单。 更多...

• 所有成员列表，包括继承的成员

属性

• 级联 : bool (自 QtQuick.Controls 2.3 (Qt 5.10))
• 内容数据 : list<QtObject>
• 内容模型 : model
• 计数 : int (自 QtQuick.Controls 2.3 (Qt 5.10))
• 当前索引 : int (自 QtQuick.Controls 2.3 (Qt 5.10))
• 代理 : Component (自 QtQuick.Controls 2.3 (Qt 5.10))
• 焦点 : bool
• 图标
  • 图标缓存 : bool
  • 图标颜色 : color
  • 图标高度 : int
  • 图标名称 : string
  • 图标资源 : url
  • 图标宽度 : int
• 重叠 : real (自 QtQuick.Controls 2.3 (Qt 5.10))
• 标题 : string

方法

• 动作 actionAt(int index) (自 QtQuick.Controls 2.3 (Qt 5.10))
• void addAction(Action action) (自 QtQuick.Controls 2.3 (Qt 5.10))
• void addItem(Item item)
• void addMenu(Menu menu) (自 QtQuick.Controls 2.3 (Qt 5.10))
• void dismiss() (自 QtQuick.Controls 2.3 (Qt 5.10))
• void insertAction(int index, Action action) (自 QtQuick.Controls 2.3 (Qt 5.10))
• void insertItem(int index, Item item)
• void insertMenu(int index, Menu menu) (自QtQuick.Controls 2.3 (Qt 5.10)以来)
• Item itemAt(int index)
• Menu menuAt(int index) (自QtQuick.Controls 2.3 (Qt 5.10)以来)
• void moveItem(int from, int to)
• void popup(MenuItem item) (自QtQuick.Controls 2.3 (Qt 5.10)以来)
• void popup(Item parent, MenuItem item) (自QtQuick.Controls 2.3 (Qt 5.10)以来)
• void popup(point pos, MenuItem item) (自QtQuick.Controls 2.3 (Qt 5.10)以来)
• void popup(Item parent, point pos, MenuItem item) (自QtQuick.Controls 2.3 (Qt 5.10)以来)
• void popup(real x, real y, MenuItem item) (自QtQuick.Controls 2.3 (Qt 5.10)以来)
• void popup(Item parent, real x, real y, MenuItem item) (自QtQuick.Controls 2.3 (Qt 5.10)以来)
• void removeAction(Action action) (自QtQuick.Controls 2.3 (Qt 5.10)以来)
• void removeItem(Item item) (自QtQuick.Controls 2.3 (Qt 5.10)以来)
• void removeMenu(Menu menu) (自QtQuick.Controls 2.3 (Qt 5.10)以来)
• Action takeAction(int index) (自QtQuick.Controls 2.3 (Qt 5.10)以来)
• MenuItem takeItem(int index) (自QtQuick.Controls 2.3 (Qt 5.10)以来)
• Menu takeMenu(int index) (自QtQuick.Controls 2.3 (Qt 5.10)以来)

详细信息

菜单有两个主要用途

• 上下文菜单；例如，在右键单击后显示的菜单
• 弹出菜单；例如，在单击按钮后显示的菜单

当用作上下文菜单时，通过调用 popup() 打开菜单是推荐的方式。除非显式指定位置，否则在具有鼠标光标的桌面平台上，菜单定位于鼠标光标处，否则在父项上方居中。

MouseArea {
    anchors.fill: parent
    acceptedButtons: Qt.LeftButton | Qt.RightButton
    onClicked: {
        if (mouse.button === Qt.RightButton)
            contextMenu.popup()
    }
    onPressAndHold: {
        if (mouse.source === Qt.MouseEventNotSynthesized)
            contextMenu.popup()
    }

    Menu {
        id: contextMenu
        MenuItem { text: "Cut" }
        MenuItem { text: "Copy" }
        MenuItem { text: "Paste" }
    }
}

当用作弹出菜单时，最简单的指定位置方法是使用相应的属性指定所需的 x 和 y 坐标，然后调用 open() 打开菜单。

Button {
    id: fileButton
    text: "File"
    onClicked: menu.open()

    Menu {
        id: menu
        y: fileButton.height

        MenuItem {
            text: "New..."
        }
        MenuItem {
            text: "Open..."
        }
        MenuItem {
            text: "Save"
        }
    }
}

如果按钮还应在单击时关闭菜单，请使用 Popup.CloseOnPressOutsideParent 标志

onClicked: menu.visible = !menu.visible

Menu {
    // ...
    closePolicy: Popup.CloseOnEscape | Popup.CloseOnPressOutsideParent

自QtQuick.Controls 2.3（Qt 5.10）以来，还可以在菜单内部创建子菜单并声明Action对象

Menu {
    Action { text: "Cut" }
    Action { text: "Copy" }
    Action { text: "Paste" }

    MenuSeparator { }

    Menu {
        title: "Find/Replace"
        Action { text: "Find Next" }
        Action { text: "Find Previous" }
        Action { text: "Replace" }
    }
}

子菜单默认为桌面平台上带有鼠标光标的平台上的级联。非级联菜单一次显示一个菜单，并相对于父菜单居中。

通常，菜单项作为菜单的子项静态声明，但菜单还提供了addItem、insertItem、moveItem以及removeItem动态添加菜单项的API。可以使用itemAt()或contentChildren访问菜单中的项。

尽管MenuItems通常与菜单一起使用，但菜单可以包含任何类型的项。

边距

由于它继承了Popup，菜单支持margins属性。默认情况下，所有内置样式都指定菜单的边距为0，以确保菜单保持在窗口范围内。要允许菜单超出窗口范围（例如，为了动画显示菜单项），请将边距属性设置为-1。

动态生成菜单项

您可以使用Instantiator或动态对象创建动态创建菜单项。

使用Instantiator

您可以使用Instantiator动态生成菜单项。以下代码演示了如何实现一个“最近文件”子菜单，其中项来自设置中存储的文件列表

Menu {
    title: qsTr("File")

    Menu {
        id: recentFilesMenu
        title: qsTr("Recent Files")
        enabled: recentFilesInstantiator.count > 0

        Instantiator {
            id: recentFilesInstantiator
            model: settings.recentFiles
            delegate: MenuItem {
                text: settings.displayableFilePath(modelData)
                onTriggered: loadFile(modelData)
            }

            onObjectAdded: (index, object) => recentFilesMenu.insertItem(index, object)
            onObjectRemoved: (index, object) => recentFilesMenu.removeItem(object)
        }

        MenuSeparator {}

        MenuItem {
            text: qsTr("Clear Recent Files")
            onTriggered: settings.clearRecentFiles()
        }
    }
}

使用动态对象创建

您还可以使用Qt.createComponent()动态从QML文件加载组件。组件准备完成后，您可以调用其createObject()方法来创建该组件的实例。

Row {
    anchors.centerIn: parent

    Component {
        id: menuItemComponent

        MenuItem {}
    }

    Button {
        id: button
        text: "Menu"
        onClicked: menu.open()
        Menu {
            id: menu
        }
    }

    Button {
        text: "Add item"
        onClicked: {
            onClicked: {
                let menuItem = menuItemComponent.createObject(
                    menu.contentItem, { text: qsTr("New item") })
                menu.addMenu(menuItem)
            }
        }
    }
}

另请参阅 自定义菜单、MenuItem、菜单控件、弹出控件以及从JavaScript动态创建QML对象。

属性说明

Menu {
    id: menu
    contentItem: ListView {
        model: menu.contentModel
    }
}

Menu {
    Action { text: "Cut" }
    Action { text: "Copy" }
    Action { text: "Paste" }
}

方法文档