TEMPLATE = app
TARGET = qtcluster
INCLUDEPATH += .
QT += quick network

# Enable for static version
#CONFIG += static
#DEFINES += STATIC
integrity: {
    CONFIG += static c++11
    DEFINES += STATIC
}

CONFIG += SPORTS_CAR
CONFIG += HYBRID_CAR

#Enable compile flags based on config flags
SPORTS_CAR: DEFINES += SPORTS_CAR
HYBRID_CAR: DEFINES += HYBRID_CAR

CONFIG += resources_big

SOURCES += \
    main.cpp \
    gauge.cpp \
    gaugenode.cpp \
    qtiviclusterdata.cpp \
    etcprovider.cpp \
    circularindicator.cpp \
    crasher.cpp

DEFINES += NO_NETWORK

RESOURCES += \
    qtcluster.qrc

RESOURCES += images.qrc

SPORTS_CAR: {
    RESOURCES += sportsqml.qrc
    RESOURCES += sportsimages.qrc
}

HYBRID_CAR: {
    RESOURCES += \
        hybridqml.qrc

RESOURCES += hybridimages.qrc
}

RESOURCES += iso-icons.qrc

ISO_ICONS = \
    iso_grs_7000_4_2423 \
    iso_grs_7000_4_1555 \
    iso_grs_7000_4_1702 \
    iso_grs_7000_4_0456 \
    iso_grs_7000_4_0249 \
    iso_grs_7000_4_0245 \
    iso_grs_7000_4_0246 \
    iso_grs_7000_4_0247 \
    iso_grs_7000_4_2426 \
    iso_grs_7000_4_1434A \
    iso_grs_7000_4_0238 \
    iso_grs_7000_4_0083

OTHER_FILES += \
    qml/* \
    qml/dash_sports/* \
    qml/dash_hybrid/* \
    qml/dash_hybrid/gauges/* \
    qml/dash_safety/* \

qnx: target.path = /tmp/saferenderer/$${TARGET}
else: target.path = $$[QT_INSTALL_EXAMPLES]/saferenderer/$${TARGET}
layoutdata.files = $$PWD/layoutData
layoutdata.path = $$[QT_INSTALL_EXAMPLES]/saferenderer/qtcluster
INSTALLS += \
    target \
    layoutdata

HEADERS += \
    gauge.h \
    gaugenode.h \
    qtiviclusterdata.h \
    etcprovider.h \
    circularindicator.h \
    crasher.h

macos: QMAKE_INFO_PLIST = Info-macos.plist
ios|tvos: QMAKE_INFO_PLIST = Info-ios.plist

CONFIG += qtsafelayouttool
SAFE_QML = $$PWD/qml/dash_hybrid/DashboardForm.ui.qml $$PWD/qml/dash_sports/DashboardSportForm.ui.qml
SAFE_LAYOUT_PATH = $$PWD/layoutData
SAFE_LAYOUT_FONTS = $$PWD/fonts
SAFE_RESOURCES = ../layoutdata.qrc